KQL : statistiques d'ingestion et d'usage dans Log Analytics
Requêtes KQL pour mesurer le volume ingéré dans Log Analytics, notamment les journaux d'audit Azure SQL.
Ce guide rassemble des requêtes KQL pour analyser le volume de données ingéré dans un espace de travail Log Analytics, en particulier les journaux d'audit Azure SQL envoyés dans la table AzureDiagnostics. Elles aident à identifier ce qui fait grimper la facturation.
Volume ingéré par base de données
AzureDiagnostics
| where ResourceProvider == "MICROSOFT.SQL"
| where database_name_s == "AppDb"
| summarize ingestedGB=sum(_BilledSize) / 1.E9, countLogs=count() by Type, bin(TimeGenerated,1d)
| render columnchart
Utilisation par solution et par type de données
La table Usage indique les volumes facturables. Quantity est exprimé en Mo, d'où la division par 1024 pour obtenir des Go.
Usage
| where TimeGenerated > startofday(ago(20d))
| where IsBillable == true
| summarize IngestedGB = sum(Quantity) / 1024 by Solution, bin(TimeGenerated, 1d)
| sort by IngestedGB desc
| render columnchart
Usage
| where TimeGenerated > startofday(ago(7d))
| where IsBillable == true and Solution == 'LogManagement'
| summarize IngestedGB = sum(Quantity) / 1024 by DataType
| sort by IngestedGB desc
| render piechart
Requêtes de synthèse sur l'audit SQL
Par catégorie :
AzureDiagnostics
| where TimeGenerated > startofday(ago(5d))
//| where Category == 'SQLSecurityAuditEvent'
| summarize ingestedGb = sum(_BilledSize) / 1024 / 1024 / 1024, cnt = count() by Category, bin (TimeGenerated,1d)
Par groupe de ressources :
AzureDiagnostics
| where TimeGenerated > startofday(ago(5d))
| where Category == 'SQLSecurityAuditEvents'
| summarize ingestedGb = sum(_BilledSize) / 1024 / 1024 / 1024, cnt = count() by ResourceGroup, bin (TimeGenerated,1d)
Par serveur logique :
AzureDiagnostics
| where TimeGenerated > startofday(ago(5d))
| where Category == 'SQLSecurityAuditEvents' //and ResourceGroup == 'my-resource-group'
| summarize ingestedGb = sum(_BilledSize) / 1024 / 1024 / 1024, cnt = count() by LogicalServerName_s, bin (TimeGenerated,1d)
Par base de données d'un serveur :
AzureDiagnostics
| where TimeGenerated > startofday(ago(5d))
| where Category == 'SQLSecurityAuditEvents' and LogicalServerName_s == 'sqlserver01'
| summarize ingestedGb = sum(_BilledSize) / 1024 / 1024 / 1024, cnt = count() by database_name_s, bin (TimeGenerated,1d)
Distinguer les vraies requêtes du bruit
L'audit enregistre aussi les instructions REVERT; et EXECUTE AS USER = ... émises par les connexions applicatives. Cette requête sépare ces événements des requêtes réelles :
AzureDiagnostics
| where TimeGenerated > startofday(ago(5d))
| where Category == 'SQLSecurityAuditEvents' and LogicalServerName_s == 'sqlserver01'
| extend emptystatement = iif(statement_s == 'REVERT;' or statement_s has 'EXECUTE AS USER = ', strcat(action_name_s, ' not real query'), strcat(action_name_s,' real query'))
| summarize ingestedGb = sum(_BilledSize) / 1024 / 1024 / 1024 by emptystatement, bin (TimeGenerated,1d)
Remarques
_BilledSizeest exprimé en octets ;Usage.Quantityen Mo.- Les noms de base, de serveur et de groupe de ressources ci-dessus sont des exemples à remplacer.