KQL : volume ingéré Log Analytics et exceptions par jour
Requêtes KQL pour le volume facturable par table et les exceptions applicatives par rôle et par jour.
Deux requêtes Kusto (KQL) utiles pour un espace de travail Log Analytics : l'ingestion facturable par table, et les exceptions applicatives par jour.
Volume ingéré facturable par table et par jour
La table Usage donne le volume ingéré facturable par type de données (DataType). La première requête retient les 10 plus grosses tables sur les 100 derniers jours, regroupe les autres sous Other et calcule le volume quotidien en Go (la colonne Quantity, en Mo, est divisée par 1 000).
let TopTables = materialize(
Usage
| where TimeGenerated > startofday(ago(100d))
| where StartTime > startofday(ago(100d))
| where IsBillable
| summarize IngestedGB=sum(Quantity) / 1.0E3 by DataType
| sort by IngestedGB desc
| take 10
| project DataType);
Usage
| where TimeGenerated > startofday(ago(100d))
| where StartTime > startofday(ago(100d))
| where IsBillable
| extend Table = iff(DataType in (TopTables), DataType, "Other")
| extend Rank = iff(Table == "Other", 2, 1)
| summarize IngestedGB=sum(Quantity) / 1.0E3 by Table, bin(StartTime, 1d), Rank
| sort by Rank asc, IngestedGB desc
| project-away Rank
| project StartTime, Table, IngestedGB
| render columnchart
Exceptions applicatives par jour
Compte les exceptions applicatives (table Application Insights AppExceptions) par rôle applicatif et par jour sur une période fixe.
AppExceptions
| where TimeGenerated between (todatetime('2024-09-01')..todatetime('2024-09-30'))
| summarize count() by AppRoleName, bin(TimeGenerated, 1d)
| render columnchart