Requêtes KQL pour superviser Azure SQL (workers, stockage, erreurs, E/S)
Requêtes Log Analytics sur AzureMetrics et AzureDiagnostics pour suivre workers, stockage, erreurs et attentes PAGEIOLATCH.
Quand les métriques et les diagnostics des bases Azure SQL (et des pools élastiques) sont envoyés vers un espace de travail Log Analytics, les tables AzureMetrics et AzureDiagnostics permettent de suivre la saturation des workers, le stockage, les erreurs et les attentes d'E/S. Voici un recueil de requêtes KQL.
Découvrir les données disponibles
// Colonnes de la table
AzureMetrics
| getschema
// Métriques disponibles
AzureMetrics
| summarize count() by MetricName
// Catégories de diagnostics disponibles
AzureDiagnostics
| summarize count() by Category
Pourcentage de workers (limite de threads)
Moyenne par tranche de 30 minutes sur les 30 derniers jours, par ressource. Fonctionne pour un pool élastique comme pour un serveur logique.
AzureMetrics
| where MetricName == "workers_percent"
| where TimeGenerated >= ago(30d) and TimeGenerated <= ago(1d)
| summarize AvgWorkersPercent = avg(Average) by Resource, bin(TimeGenerated, 30m)
| project TimeGenerated, Resource, AvgWorkersPercent
| render timechart
Pics de workers, triés par maximum :
AzureMetrics
| where MetricName == "workers_percent"
| project TimeGenerated, ResourceId, Resource, Average, Maximum
| order by Maximum desc
Métriques des pools élastiques
AzureMetrics
| where ResourceId contains "elasticPools"
| where MetricName in ("cpu_percent", "storage_percent", "io_percent", "log_write_percent")
| project TimeGenerated, Resource, ResourceGroup, MetricName, Average, Maximum
| order by TimeGenerated desc
Pourcentage de stockage
AzureMetrics
| where MetricName == "storage_percent"
| project TimeGenerated, ResourceId, Resource, Average, Maximum
| order by TimeGenerated desc
Stockage de données alloué pour une base (en Go)
AzureMetrics
| where Resource contains 'sqldb-example-01'
| where MetricName contains 'allocated_data_storage'
| summarize avg(Total) by bin(TimeGenerated, 1h)
| extend AvgAllocatedDataStorage_GB = avg_Total / (1024 * 1024 * 1024)
| project TimeGenerated, AvgAllocatedDataStorage_GB
| render timechart
Erreurs
Nombre d'erreurs par groupe de ressources :
AzureDiagnostics
| where Category == 'Errors'
| summarize count() by ResourceGroup
| order by count_ desc
Détail des erreurs d'un groupe de ressources, en excluant les messages « read-only » :
AzureDiagnostics
| where Category == 'Errors'
| where ResourceGroup == 'rg-example'
| where Message !contains 'read-only'
Attentes PAGEIOLATCH par heure
Durée totale des attentes pageiolatch par base et par heure, pour une journée donnée :
AzureDiagnostics
| where TimeGenerated between (datetime(2025-01-15 00:00:00) .. endofday(datetime(2025-01-15 00:00:00)))
| where ResourceProvider == 'MICROSOFT.SQL' and wait_type_s has 'pageiolatch'
| where Resource matches regex 'SQLDB-EXAMPLE-DB[0-9][0-9][0-9][0-9][0-9]$'
| summarize total_duration_s = sum(delta_wait_time_ms_d) / 1000 by Resource, bin(TimeGenerated, 1h)
| where total_duration_s >= 0.1
| extend MetricDate = format_datetime(TimeGenerated, 'yyyy-MM-dd'),
MetricTime = format_datetime(TimeGenerated, 'HH:mm'),
MetricName = 'pageiolatch_waits'
Remarques
- Les noms de bases, de groupes de ressources et l'expression régulière sont des exemples génériques à adapter.
- Les tables et colonnes disponibles dépendent des paramètres de diagnostic activés sur les ressources.