LLI Wiki — My Digital Knowledge Base

KQL : retrouver les transactions longues dans Azure SQL Database

Requêtes KQL sur AzureDiagnostics pour lister les requêtes d'une transaction et détecter les transactions longues.

Avec les diagnostics d'Azure SQL Database (audit) envoyés vers Log Analytics, la table AzureDiagnostics permet de retrouver les transactions d'une base et d'identifier celles qui durent longtemps. Les requêtes ci-dessous sont écrites en KQL.

Toutes les requêtes d'une transaction

AzureDiagnostics
| where ResourceProvider == "MICROSOFT.SQL" and database_name_s == 'sqldb-example'
| where transaction_id_d == 123456789
| project TimeGenerated, statement_s, duration_milliseconds_d, action_name_s, succeeded_s, transaction_id_d

Toutes les transactions d'une session

Pour une base et un session_id donnés :

AzureDiagnostics
| where ResourceProvider == "MICROSOFT.SQL" and database_name_s == 'sqldb-example'
| where action_name_s has 'transaction' and session_id_d == 192
| project TimeGenerated, statement_s, duration_milliseconds_d, action_name_s, succeeded_s, transaction_id_d, session_id_d

Transactions longues

La requête apparie chaque événement TRANSACTION BEGIN COMPLETED avec l'événement suivant de la même session et de la même base (commit ou rollback), puis calcule la durée en secondes. Ici le seuil est TransactionDur > 5 : adapter la valeur (par exemple 30 pour les transactions de plus de 30 secondes).

let transactionInfo =
AzureDiagnostics
//| where TimeGenerated >= datetime("2024-01-01 00:00") and TimeGenerated <= datetime("2024-01-01 10:00")
| where ResourceProvider == "MICROSOFT.SQL" and database_name_s has 'sqldb-example' //and session_id_d == 52
| where action_name_s has 'transaction'
| project TimeGenerated, event_time_t, action_name_s, transaction_id_d, session_id_d, database_name_s
| extend ActionOrder = iif(action_name_s == 'TRANSACTION BEGIN COMPLETED',1,2)
| order by database_name_s, session_id_d asc, event_time_t asc, ActionOrder asc
| extend TransactionEnd = iif(action_name_s == 'TRANSACTION BEGIN COMPLETED' and session_id_d == next(session_id_d) and database_name_s == next(database_name_s), next(TimeGenerated), datetime(null))
| extend TransactionDur = datetime_diff('second',TransactionEnd,TimeGenerated)
| extend TransactionSucceeded = iif(next(action_name_s) == 'TRANSACTION ROLLBACK COMPLETED','rollback','commit');
transactionInfo
| where action_name_s == 'TRANSACTION BEGIN COMPLETED' and TransactionDur > 5
| project TimeGenerated, TransactionEnd, transaction_id_d, session_id_d, TransactionDur, TransactionSucceeded
//| order by database_name_s asc, TimeGenerated asc

Remarques

Mastodon LLIMastodon SocialFosstodon