LLI Wiki — My Digital Knowledge Base

KQL : trouver les comptes les plus touchés par la latence dans Application Insights

Requêtes KQL sur la table requests et performanceBucket pour repérer les requêtes lentes par compte.

Requêtes KQL pour Application Insights (table requests) afin de repérer les comptes ou utilisateurs qui subissent de la latence. La colonne performanceBucket classe chaque requête par durée (<250ms, 250ms-500ms, 500ms-1sec, 1sec-3sec, 3sec-7sec, ...). Ouvrir la ressource Application Insights, puis Logs.

Requêtes lentes dans le temps, par compte

requests
| where performanceBucket in ("3sec-7sec","1sec-3sec")
| summarize count() by bin(timestamp,5m),user_AccountId
| render timechart

Répartition des requêtes lentes pour un compte

requests
| where user_AccountId == "account01"
| where performanceBucket !in ("<250ms","250ms-500ms","500ms-1sec")
| summarize count() by bin(timestamp,5m),performanceBucket
| render timechart

Les 5 comptes avec le plus de requêtes lentes

requests
| where performanceBucket !in ("<250ms", "250ms-500ms", "500ms-1sec")
| summarize BadPerformanceCount = count() by user_AccountId
| top 5 by BadPerformanceCount
| project user_AccountId;

Évolution des requêtes lentes pour ces 5 comptes

let Top5Users = requests
    | where isnotempty(user_AccountId)
    | where performanceBucket !in ("<250ms", "250ms-500ms", "500ms-1sec")
    | summarize BadPerformanceCount = count() by user_AccountId
    | top 5 by BadPerformanceCount
    | project user_AccountId;
requests
    | where isnotempty(user_AccountId)
    | where user_AccountId in (Top5Users)
    | where performanceBucket !in ("<250ms", "250ms-500ms", "500ms-1sec")
    | summarize Count = count() by bin(timestamp, 10m), user_AccountId, performanceBucket
    | render timechart

Isoler une plage horaire

let StartTime = datetime(2025-01-20T08:00:00Z);
let EndTime = datetime(2025-01-20T10:00:59Z);
requests
| where performanceBucket == "1sec-3sec"
| where user_AccountId == "account01"
| where timestamp >= StartTime and timestamp <= EndTime

Pour analyser les requêtes elles-mêmes, utiliser ensuite Transaction search dans le menu de la ressource.

Captures d'écran

Application Insights, onglet Logs : requêtes KQL et graphique des requêtes lentes par compte

Mastodon LLIMastodon SocialFosstodon