SQL Server : ajouter des fichiers de données à tempdb et les déplacer
Générer les instructions pour ajouter des fichiers de données à tempdb, puis pour déplacer ses fichiers vers un autre dossier.
Deux scripts pour configurer tempdb. Le premier ajoute des fichiers de données jusqu'à ce que leur nombre soit égal au nombre de processeurs logiques ; il ne fait qu'afficher les instructions ALTER DATABASE (l'exécution est commentée). Le second génère les instructions qui déplacent les fichiers de tempdb vers un autre dossier.
Ajouter des fichiers de données
Les nouveaux fichiers sont créés dans le même dossier que le fichier tempdev existant.
USE [master]
GO
DECLARE @cpu_count int, @file_count int, @logical_name sysname, @file_name nvarchar(520), @physical_name nvarchar(520), @alter_command nvarchar(max)
SELECT
@physical_name = physical_name
FROM tempdb.sys.database_files
WHERE
name = 'tempdev'
SELECT
@file_count = COUNT(*)
FROM
tempdb.sys.
database_files
WHERE
type_desc = 'ROWS'
SELECT
@cpu_count = cpu_count
FROM
sys.dm_os_sys_info
WHILE @file_count < @cpu_count
BEGIN
SELECT @logical_name = 'tempdev' + CAST(@file_count AS nvarchar)
SELECT @file_name = REPLACE(@physical_name, 'tempdb.mdf', @logical_name + '.ndf')
SELECT @alter_command = 'ALTER DATABASE [tempdb] ADD FILE ( NAME =N''' + @logical_name + ''', FILENAME =N''' + @file_name + ''', SIZE = 100MB, FILEGROWTH = 50MB )'
PRINT @alter_command
--EXEC sp_executesql @alter_command
SELECT @file_count = @file_count + 1
END
Déplacer les fichiers de tempdb
Cette requête ne modifie rien : elle génère une instruction ALTER DATABASE tempdb MODIFY FILE par fichier, vers D:\SQLData\.
SELECT 'ALTER DATABASE tempdb MODIFY FILE (NAME = [' + f.name + '],'
+ ' FILENAME = ''D:\SQLData\' + f.name
+ CASE WHEN f.type = 1 THEN '.ldf' ELSE '.mdf' END
+ ''');'
FROM sys.master_files f
WHERE f.database_id = DB_ID(N'tempdb');
Remarques
- Le dossier cible doit exister et le compte de service de SQL Server doit y avoir les droits d'écriture.
- Le déplacement prend effet au prochain redémarrage de l'instance.
- Le script de déplacement applique l'extension
.mdfà tous les fichiers de données ; adaptez-la si vous voulez distinguer les fichiers principaux des fichiers secondaires.