Lister les échecs de connexion du journal d'erreurs sur 7 jours
Compter les échecs de connexion SQL Server des sept derniers jours à partir des archives du journal d'erreurs.
Ce script lit les archives du journal d'erreurs SQL Server et regroupe, par texte de message, les échecs de connexion des sept derniers jours. Pour chaque message, il affiche le nombre de tentatives et les dates de la première et de la dernière occurrence.
Script
DECLARE @ErrorLogCount INT
DECLARE @LastLogDate DATETIME
DECLARE @ErrorLogInfo TABLE (
LogDate DATETIME
,ProcessInfo NVARCHAR (50)
,[Text] NVARCHAR (MAX)
)
DECLARE @EnumErrorLogs TABLE (
[Archive#] INT
,[Date] DATETIME
,LogFileSizeMB INT
)
INSERT INTO @EnumErrorLogs
EXEC sp_enumerrorlogs
SELECT @ErrorLogCount = MIN([Archive#]), @LastLogDate = MAX([Date])
FROM @EnumErrorLogs
WHILE @ErrorLogCount IS NOT NULL
BEGIN
INSERT INTO @ErrorLogInfo
EXEC sp_readerrorlog @ErrorLogCount
SELECT @ErrorLogCount = MIN([Archive#]), @LastLogDate = MAX([Date])
FROM @EnumErrorLogs
WHERE [Archive#] > @ErrorLogCount
AND @LastLogDate > getdate() - 7
END
-- List all last week failed logins count of attempts and the Login failure message
SELECT COUNT (TEXT) AS NumberOfAttempts, TEXT AS Details, MIN(LogDate) as MinLogDate, MAX(LogDate) as MaxLogDate
FROM @ErrorLogInfo
WHERE ProcessInfo = 'Logon'
AND TEXT LIKE '%fail%'
AND LogDate > getdate() - 7
GROUP BY TEXT
ORDER BY NumberOfAttempts DESC
SET NOCOUNT OFF
Fonctionnement
sp_enumerrorlogsliste les archives du journal d'erreurs.sp_readerrorloglit chaque archive dans une variable de table.- Le
SELECTfinal garde les lignes dontProcessInfovautLogon, dont le texte contientfailet dont la date est dans les sept derniers jours. - Les résultats sont triés par nombre de tentatives, le message le plus fréquent en premier.
Remarques
- Le résultat dépend de la rétention du journal d'erreurs : les archives supprimées ne peuvent pas être lues.
- Chaque texte de message distinct forme une ligne ; un même compte apparaissant dans des messages différents donne donc plusieurs lignes.