Azure SQL : repérer les requêtes longues dans les logs d'audit avec KQL
Deux requêtes KQL sur la catégorie SQLSecurityAuditEvents : nombre d'instructions longues par base, puis instructions longues regroupées par texte.
Azure SQL Database peut envoyer ses événements d'audit vers un espace de travail Log Analytics. La catégorie SQLSecurityAuditEvents arrive dans la table AzureDiagnostics, avec le texte de l'instruction et sa durée en millisecondes. Les deux requêtes ci-dessous exploitent ces données pour repérer les instructions lentes. Elles gardent les instructions de plus de 1 seconde (1000 ms) et ignorent les instructions contenant hangfire, un filtre d'exemple pour une bibliothèque de tâches en arrière-plan ; le retirer si ce n'est pas pertinent.
Nombre d'instructions longues par base
//------------------------- scope sql server -------------
//number of long queries per database
AzureDiagnostics
| where ResourceProvider == 'MICROSOFT.SQL'
| where statement_s !has 'hangfire' and duration_milliseconds_d > 1000
| where Category == 'SQLSecurityAuditEvents'
| summarize CountValue = count(), AvgDuration = avg(duration_milliseconds_d), TotalDuration = sum(duration_milliseconds_d) by bin(TimeGenerated, 60m), server_instance_name_s, database_name_s
| extend AvgDurationDescr = case (
AvgDuration < 1000, strcat( round(AvgDuration,1) ,'ms'),
AvgDuration >= 1000 and AvgDuration < 60000, strcat(round(AvgDuration / 1000 ,1) , 'sec'),
AvgDuration >= 60000, strcat(round(AvgDuration / 1000 / 60 ,1) , 'min'),
strcat(AvgDuration, ''))
| extend TotalDurationDescr = case (
TotalDuration < 1000, strcat( round(TotalDuration,1) ,'ms'),
TotalDuration >= 1000 and TotalDuration < 60000, strcat(round(TotalDuration / 1000 ,1) , 'sec'),
TotalDuration >= 60000 and TotalDuration < 3600000, strcat(round(TotalDuration / 1000 / 60 ,1) , 'min'),
TotalDuration >= 3600000 and TotalDuration < 86400000, strcat(round(TotalDuration / 1000 / 60 / 60 ,1) , 'hr'),
TotalDuration >= 86400000, strcat(round(TotalDuration / 1000 / 60 / 60 / 24 ,1) , 'day'),
strcat(TotalDuration, ''))
Instructions longues regroupées par texte
La requête coupe chaque instruction avant sa liste de paramètres (N'@...), afin que la même instruction avec des valeurs différentes soit comptée une seule fois.
//List of long queries, including avg duration and distinct count of databases
AzureDiagnostics
| where ResourceProvider == 'MICROSOFT.SQL'
| where statement_s !has 'hangfire' and duration_milliseconds_d > 1000
| where Category == 'SQLSecurityAuditEvents'
| extend placeOfSeparation = indexof(statement_s,"N'@"), lengthStatement = strlen(statement_s)
| extend partOfQuery = case(placeOfSeparation==-1,statement_s , substring(statement_s,0,lengthStatement - (lengthStatement - placeOfSeparation)))
| summarize CountValue = count(), DiffDb = dcount(database_name_s), AvgDuration = round(avg(duration_milliseconds_d),0), TotalDuration = sum(duration_milliseconds_d) by bin(TimeGenerated, 7d), partOfQuery
| extend AvgDurationDescr = case (
AvgDuration < 1000, strcat( round(AvgDuration,1) ,'ms'),
AvgDuration >= 1000 and AvgDuration < 60000, strcat(round(AvgDuration / 1000 ,1) , 'sec'),
AvgDuration >= 60000, strcat(round(AvgDuration / 1000 / 60 ,1) , 'min'),
strcat(AvgDuration, ''))
| extend TotalDurationDescr = case (
TotalDuration < 1000, strcat( round(TotalDuration,1) ,'ms'),
TotalDuration >= 1000 and TotalDuration < 60000, strcat(round(TotalDuration / 1000 ,1) , 'sec'),
TotalDuration >= 60000 and TotalDuration < 3600000, strcat(round(TotalDuration / 1000 / 60 ,1) , 'min'),
TotalDuration >= 3600000 and TotalDuration < 86400000, strcat(round(TotalDuration / 1000 / 60 / 60 ,1) , 'hr'),
TotalDuration >= 86400000, strcat(round(TotalDuration / 1000 / 60 / 60 / 24 ,1) , 'day'),
strcat(TotalDuration, ''))
| order by CountValue desc;
Remarques
- La catégorie d'audit doit être activée dans les paramètres de diagnostic de la base ou du serveur pour que ces lignes existent.